***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*May 04, 2018                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt BAS16 1 2 3
.param
+vc0 = 5.742e-9		 vc1 = 8.025e-11	 vc2 = 1.072e-13
+tc1 = 8.085e-2		 tc2 = 4.032e-2		
d1 1 3 diode
g1 3 1 value = {(vc0+vc1*v(3,1)+vc2*v(3,1)*v(3,1))*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))}
.model diode d
***** flag parameter *****
+level = 1
***** dc model parameter *****
+ is = 6.515e-9		   n = 1.992		  rs = 1.038		 ikf = 0.05
+ibv = 0.1e-3		 nbv = 1		  bv = 110
***** capacitance parameter *****
+cjo = 4.758e-13	   m = 2.515e-2		  vj = 2.349e-1
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 1.150		 xti = 3
+trs1 = 2.231e-4	trs2 = 7.025e-6		tikf = -1e-4		
.ends BAS16
*$
